***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 09, 2018                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt SBA130CS A K 
.param
+vc0 = 5.517e-1
+vc1 = 5.841e-2
+vc2 = 1.672e-2
+tc1 = 6.075e-2
+tc2 = 3.333e-2
gdiode K A value={(vc0+vc1*v(K,A)+vc2*v(K,A)*v(K,A))*1e-6*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d1 A K sbd
.model sbd d
***** flag parameter ***
+level = 1 
***** dc model parameter ***
+ is = 3.682e-6
+  n = 1.086
+ rs = 7.531e-2 
+ikf = 1.320
+ibv = 0.5e-3  
+ bv = 33
***** capacitance parameter ***
+cjo = 5.304e-10  
+  m = 6.984e-1
+ vj = 1.593e-1 
+ fc = 0.5 
***** temperature coefficient ***
+tnom = 25 
+  eg = 5.112e-1 
+ xti = 3 
+trs1 = 4.465e-3
+trs2 = 1.207e-6 
.ends SBA130CS
*$
